👾 Learning Solidity

How to Interact with ERC-721 Tokens in Solidity

Learn how to interact with, and build on top of existing ERC-721 tokens using Solidity

One of the greatest benefits of NFTs (and smart contracts, in general) is universal interoperability. Any contract on a blockchain can theoretically interact and build on top of any other contract on the same blockchain.

600

Crypto Coven NFTs

Interoperability helps NFT collections provide continuing utility to their holders, allows other projects to entice top buyers with discounts and exclusive access, and in some cases allows creators to do damage control for security breaches in the original contract.

In a previous tutorial, we learned how to interact with existing ERC-721 tokens to create custom allowlists. In this tutorial, we will explore a more advanced case. We will write a smart contract using Solidity and Hardhat that allows users who have paid and minted NFTs from a compromised contract to mint the same token IDs from a new contract for free.

Creating the Interaction Contract

Imagine you are the creator of an NFT project. You launch a collection and your buyers start minting NFTs by paying a certain amount of ETH. However, after a point of time, you realize that you haven’t added functionality to your contract to withdraw the ETH that buyers have paid.

You immediately halt any further sales. You decide to launch a new contract but you do not want buyers who have already paid and minted their NFTs to pay a price again. This project will explore how we go about handling this.

Interacting with other ERC-721 contracts

In order to interact with any ERC-721 contract deployed on the blockchain of your choice, you will need to setup the following in your own contract:

  1. Define a Solidity interface that lists all the functions (and their signatures) that you plan on calling.
  2. Define an instance of the interface using the address of the contract you want to interface with.
  3. Call the functions listed in the interface.

A very simple example would look something like this:

sol
1//SPDX-License-Identifier: MIT
2pragma solidity ^0.8.9;
3
4import "@openzeppelin/contracts/access/Ownable.sol";
5import "@openzeppelin/contracts/token/ERC721/extensions/ERC721Enumerable.sol";
6
7interface OGContractInterface {
8    function functionToCall1() external view returns (uint);
9    function functionToCall2() external view returns (uint);
10    ...
11}
12
13contract MyContract is Ownable, ERC721Enumerable {
14
15    // Deployed address of contract we want to interface with
16    address public ogContractAddress;
17    OGCollectionInterface ogContract;
18
19    constructor(address _ogContractAddress) ERC721("My Collection", "MC") {
20
21        // Connect to the original NFT smart contract and get an instance
22        ogContractAddress = _ogContractAddress;
23        ogContract = OGCollectionInterface(ogContractAddress);
24    }
25
26    // Call original contract's methods inside your contract
27    function myFunction() public onlyOwner {
28        ogContract.functionToCall1();
29        ogContract.functionToCall2();
30    }
31}

In the following sections, we will implement a more concrete solution for the problem highlighted above.

Step 1: Install Node and npm

In case you haven’t already, install node and npm on your local machine. Make sure that node is at least v14 or higher by typing the following in your terminal:

$node -v

Step 2: Create a Hardhat project

We’re going to set up our project using Hardhat, the industry-standard development environment for Ethereum smart contracts. Additionally, we’ll also install OpenZeppelin contracts.

To set up Hardhat, run the following commands in your terminal:

bash
$mkdir nft-interaction && cd nft-interaction
>npm init -y
>npm install --save-dev hardhat
>npx hardhat

Choose Create a Javascript project from the menu and accept all defaults. To ensure everything is installed correctly, run the following command in your terminal:

bash
$npx hardhat test

To install OpenZeppelin:

bash
$npm install @openzeppelin/contracts

Step 3: Write the incorrect NFT smart contract

Let’s now create the original (but incorrect) NFT smart contract. This contract will have all the basic functionalities expected of an NFT PFP collection except the withdraw function.

Open the nft-interaction project in your favorite code editor (e.g. VS Code). Create a file named ICNft.sol in the contracts folder and add the following code:

sol
1//SPDX-License-Identifier: MIT
2pragma solidity ^0.8.9;
3
4import "@openzeppelin/contracts/access/Ownable.sol";
5import "@openzeppelin/contracts/token/ERC721/extensions/ERC721Enumerable.sol";
6
7contract ICNft is Ownable, ERC721Enumerable {
8
9    uint private _tokenIds;
10
11    uint public constant price = 0.05 ether;
12
13    string public baseTokenURI;
14
15    bool public saleIsActive = true;
16
17    constructor() ERC721("Original Collection", "OGC") {
18    }
19
20    // Set Sale state
21    function setSaleState(bool _activeState) public onlyOwner {
22        saleIsActive = _activeState;
23    }
24
25    // Mint NFTs
26    function mintNfts(uint _count) public payable {
27        require(saleIsActive, "Sale is not currently active!");
28        require(msg.value >= price * _count, "Not enough ether to purchase.");
29
30        for (uint i = 0; i < _count; i++) {
31            _mintSingleNft();
32        }
33    }
34
35    // Mint a single NFT
36    function _mintSingleNft() private {
37        uint newTokenID = _tokenIds;
38        _safeMint(msg.sender, newTokenID);
39        _tokenIds = _tokenIds + 1;
40    }
41
42    // Get tokens of an owner
43    function tokensOfOwner(address _owner) public view returns (uint[] memory) {
44
45        uint tokenCount = balanceOf(_owner);
46        uint[] memory tokensId = new uint256[](tokenCount);
47
48        for (uint i = 0; i < tokenCount; i++) {
49            tokensId[i] = tokenOfOwnerByIndex(_owner, i);
50        }
51        return tokensId;
52    }
53}

Step 4: Write the replacement NFT smart contract

Our replacement smart contract will implement all the functionalities of the original smart contract (plus withdrawal) and add a remint feature.

Remint will allow users who have NFTs from the original contract to mint the corresponding IDs on the new contract without having to pay the base price. This will be done by calling the tokensOfOwner function in the original contract.

To make sure that our contract can actually call the aforementioned function, we need to provide it with the function’s signature. We will do this using Solidity interfaces.

In the contracts folder, create another file named RCNft.sol and add the following code:

sol
1//SPDX-License-Identifier: MIT
2pragma solidity ^0.8.9;
3
4import "@openzeppelin/contracts/access/Ownable.sol";
5import "@openzeppelin/contracts/token/ERC721/extensions/ERC721Enumerable.sol";
6
7interface ICCollectionInterface {
8    // Define signature of tokensOfOwner
9    function tokensOfOwner(address _owner) external view returns (uint[] memory);
10
11    // Definte signature of totalSupply
12    function totalSupply() external view returns (uint);
13}
14
15contract RCNft is Ownable, ERC721Enumerable {
16
17    uint private _tokenIds;
18
19    uint public constant price = 0.05 ether;
20
21    string public baseTokenURI;
22
23    bool public saleIsActive = false;
24
25    // Mapping that keeps track of all reminted NFTs
26    mapping(uint => bool) private isReminted;
27
28    // Deployed address of original collection
29    address public icContractAddress;
30    ICCollectionInterface icContract;
31
32    constructor(address _icContractAddress) ERC721("Replacement Collection", "RC") {
33
34        // Connect to the original NFT smart contract and get an instance
35        icContractAddress = _icContractAddress;
36        icContract = ICCollectionInterface(icContractAddress);
37
38        // Set current token ID to total supply of old collection 
39        // Done to allow only reminting of NFTs already minted in the old collection
40        _tokenIds = icContract.totalSupply();
41    }
42
43    // Set Sale state
44    function setSaleState(bool _activeState) public onlyOwner {
45        saleIsActive = _activeState;
46    }
47
48    // Mint NFTs
49    function mintNfts(uint _count) public payable {
50        require(saleIsActive, "Sale is not currently active!");
51        require(msg.value >= price * _count, "Not enough ether to purchase.");
52
53        for (uint i = 0; i < _count; i++) {
54            _mintSingleNft();
55        }
56    }
57
58    // Remint NFTs
59    function remintNfts() public {
60
61        uint[] memory ids = icContract.tokensOfOwner(msg.sender);
62
63        // Only remint if it hasn't been done already
64        for (uint i = 0; i < ids.length; i++) {
65            if (!isReminted[ids[i]]) {
66                _safeMint(msg.sender, ids[i]);
67                isReminted[ids[i]] = true;
68            }
69        }
70
71    }
72
73    // Mint a single NFT
74    function _mintSingleNft() private {
75        uint newTokenID = _tokenIds;
76        _safeMint(msg.sender, newTokenID);
77        _tokenIds + _tokenIds + 1;
78    }
79
80    // Get tokens of an owner
81    function tokensOfOwner(address _owner) external view returns (uint[] memory) {
82
83        uint tokenCount = balanceOf(_owner);
84        uint[] memory tokensId = new uint256[](tokenCount);
85
86        for (uint i = 0; i < tokenCount; i++) {
87            tokensId[i] = tokenOfOwnerByIndex(_owner, i);
88        }
89        return tokensId;
90    }
91
92    // Withdraw ether
93    function withdraw() public payable onlyOwner {
94        uint balance = address(this).balance;
95        require(balance > 0, "No ether left to withdraw");
96
97        (bool success, ) = (msg.sender).call{value: balance}("");
98        require(success, "Transfer failed.");
99    }
100}

The contract ensures the following:

  1. NFTs that had already been minted in the old collection can only be reminted by existing owners. These NFTs won’t be available for public sale.
  2. All NFTs that were not minted in the old collection will be available for public sale and will function as expected.

Compile the contracts and make sure everything is working by running:

bash
$npx hardhat compile

Step 5: Simulate functionality locally

Let’s now simulate our functionality locally. We will write a script that sequentially does the following:

  1. Owner deploys the original (incorrect) NFT smart contract
  2. Wallet 1 mints three NFTs (IDs 0, 1, and 2) by paying 0.15 ETH.
  3. Wallet 2 mints two NFTs (IDs 3 and 4) by paying 0.1 ETH.
  4. Owner realizes mistake and halts sales.
  5. Owner deploys the replacement NFT smart contract.
  6. Wallet 2 mints NFTs 3 and 4 from the replacement contract without paying a price.

Create a new file called run.js in the scripts folder, and add the following code:

sol
1const hre = require("hardhat");
2const { utils } = require("ethers");
3
4async function main() {
5
6    // Get wallet addresses from hardhat
7    const [owner, address1, address2] = await hre.ethers.getSigners();
8
9    // Deploy OG (incorrect) collection and get deployed contract address
10    const icFactory = await hre.ethers.getContractFactory("ICNft");
11    const icContract = await icFactory.deploy();
12
13    await icContract.deployed();
14    console.log("OG Collection deployed to: ", icContract.address, "\n");
15
16    icContractAddress = icContract.address
17
18    // Mint 3 OG NFTs to address1
19    let txn;
20    txn = await icContract.connect(address1).mintNfts(3, { value: utils.parseEther('0.15') });
21    await txn.wait()
22    console.log("3 OG NFTs minted to ", address1.address);
23
24    // Mint 2 OG NFTs to address2
25    txn = await icContract.connect(address2).mintNfts(2, { value: utils.parseEther('0.10') });
26    await txn.wait()
27    console.log("2 OG NFTs minted to ", address2.address);
28
29    // Freeze sales of OG collection
30    txn = await icContract.setSaleState(false);
31    await txn.wait();
32    console.log("OG Collection sales have been halted");
33
34    // Deploy replacement contract
35    const rcFactory = await hre.ethers.getContractFactory("RCNft");
36    const rcContract = await rcFactory.deploy(icContractAddress);
37
38    await rcContract.deployed();
39    console.log("\nReplacement Collection deployed to: ", rcContract.address, "\n");
40
41    // Remint NFTs belonging to address2
42    txn = await rcContract.connect(address2).remintNfts();
43    await txn.wait()
44    console.log("NFTs reminted to ", address2.address);
45
46    let ids = await rcContract.tokensOfOwner(address2.address);
47    ids = ids.map(x => x.toNumber())
48    console.log("Replacement NFTs reminted:", ids);
49}
50
51main()
52    .then(() => process.exit(0))
53    .catch((error) => {
54        console.error(error);
55        process.exit(1);
56    });

Run this script by running the following command in your terminal:

bash
$npx hardhat run scripts/run.js

You should see output that looks like this:

bash
$OG Collection deployed to:  0x5FbDB2315678afecb367f032d93F642f64180aa3 
>
>3 OG NFTs minted to  0x70997970C51812dc3A010C7d01b50e0d17dc79C8
>2 OG NFTs minted to  0x3C44CdDdB6a900fa2b585dd299e03d12FA4293BC
>OG Collection sales have been halted
>
>Replacement Collection deployed to:  0x9fE46736679d2D9a65F0992F2272dE9f3c7fa6e0 
>
>NFTs reminted to  0x3C44CdDdB6a900fa2b585dd299e03d12FA4293BC
>Replacement NFTs reminted: [ 3, 4 ]

Conclusion

Congratulations! You now know how to interact with ERC-721 tokens and smart contracts on any EVM-based blockchain using Solidity.

If you enjoyed this tutorial about creating on-chain allowlists, tweet us at @Alchemy and give us a shoutout!

Don’t forget to join our Discord server to meet other blockchain devs, builders, and entrepreneurs!

Ready to start building your NFT collection?

Create a free Alchemy account and do share your project with us!